[help] Alberta Daily Quest for Valkyrie Server pRO

[raine101]

automacro capcha-a {
console /location 194, 217/i
exclusive 1
priority 3
call solved-a
}

automacro capcha-b {
console /location 194, 168/i
exclusive 1
priority 2
call solved-b
}

automacro capcha-c {
console /location 265, 88/i
exclusive 1
priority 1
call solved-c
}

macro solved-a {
pause 2
do talk text 1
release capcha-a
}

macro solved-b {
pause 2
do talk text 2
release capcha-b
}

macro solved-c {
pause 2
do talk text 3
release capcha-c
}

Here's the macro that I tried to use however, as EternalHarvest said, it won't work unless it's hooked to the mini-map indicator...

Now here's the tricky part, the "hooking to the mini-map indicator" is sorta new to me..

So we were hoping that you can help us with this...

[ever_boy_]

try this:

Code: Select all

automacro countBoats {
	console /^NPC \[Quest\] Port Manager# \(\d+\) shown minimap indicator/i
	call {
		[
		$i++
		]
	}
}
automacro answerBoats {
	console /^NPC \[Quest\] Port Manager#^: Type/i
	call {
		do talk text $i
		$i = 0
	}
}

can't test it as I don't have this quest on my server.

[raine101]

Thanks for the response...

I've tried the macro that you have provided and it does count the number of coordinates the npc is giving...

However, the automacro "answerBoats" failed to initialize...



As you can see in the screenshot, even if the npc asks for an answer which is the condition for the answerBoats automacro, it fails to give an answer which leads to manual intervention or inputting...

console /^NPC \[Quest\] Port Manager#^: Type/i

Is there anyway that we can call the automacro answerBoats (or make it a macro then call it) right after we have counted the number of coordinates provided that way, we can be sure that an answer will be given?

Thanks and more power...

***EDIT****

I've noticed that Kore stops workng if it talks to the port NPC again (below is the screenshot)...



Kore is giving the response that it was supposed to give the first time it talks with the NPC...

But since there is no question or text box, the NPC will naturally give no response thus disconnecting the Kore..

[NiTRO27]

i have the same problem with yours raine101. but i revised the code that ever_boy_ did yesterday.

Code: Select all

automacro countBoats {
	console /^NPC \[Quest\] Port Manager# \(\d+\) shown minimap indicator/i
	call {
		$i++
	}
	call answerBoats
}
macro answerBoats {
	pause 2
	do talk text $i
	do c $i
	$i = 0
	release countBoats
}

that script tells OpenKore that after countBoats has been finished counting the minimap indicators, it will call now the answerBoats macro. it works at first but after you pick the first crate and the character will talk the NPC again, the macro answerBoats will not trigger.

EDIT: the macro will only work at the start but after the bot talked the first crate and will go back to the same NPC, the answerBoats will not trigger, thus disconnecting the bot to the server. here is the code that i revised. BTW, this macro came from noobotter.

Code: Select all

automacro AlbertaCargoDeliveryQuest {
	priority 1
	run-once 1
	location alberta
	call {
		$randomHX = @random ("94","95","96","97","98")
       		$randomHY = @random ("60","61","62","63","64")
       		do move alberta $randomHX $randomHY
		do talknpc 90 62 c c c r0 c c n
		stop
	}
}

automacro countBoats {
	console /^NPC \[Quest\] Port Manager# \(\d+\) shown minimap indicator/i
	call {
		[
		$i++
		]
	}
	}

automacro answerBoats {
	console /^\[Quest\] Port Manager#: Type 'talk text'/i
	call {
		do talk text $i
		$i = 0
	}
}

automacro 1stBracket {
	console /You can easily recognize the first crate/
	base >= 1
	base <= 20
	exclusive 1
	run-once 1
	call {
		call 1stCrate
		call HomeNPC
		log 1st Crate done!
		log Quest Complete!
		stop
	}
}

automacro 2ndBracket {
	console /You can easily recognize the first crate/
	base >= 21
	base <= 40
	exclusive 1
	run-once 1
	call {
		call 1stCrate
		call HomeNPC
		log 1st Crate done!
		call 2ndCrate
		call HomeNPC
		log 2nd Crate done!
		log Quest Complete!
		stop
	}
}

automacro 3rdBracket {
	console /You can easily recognize the first crate/
	base >= 41
	base <= 60
	exclusive 1
	run-once 1
	call {
		call 1stCrate
		call HomeNPC
		log 1st Crate done!
		call 2ndCrate
		call HomeNPC
		log 2nd Crate done!
		call 3rdCrate
		call HomeNPC
		log 3rd Crate done!
		log Quest Complete!
		stop
	}
}

automacro 4thBracket {
	console /You can easily recognize the first crate/
	base >= 61
	base <= 80
	exclusive 1
	run-once 1
	call {
		call 1stCrate
		call HomeNPC
		log 1st Crate done!
		call 2ndCrate
		call HomeNPC
		log 2nd Crate done!
		call 3rdCrate
		call HomeNPC
		log 3rd Crate done!
		call 4thCrate
		call HomeNPC
		log 4th Crate done!
		log Quest Complete!
		stop
	}
}

automacro 5thBracket {
	console /You can easily recognize the first crate/
	base >= 81
	base <= 97
	exclusive 1
	run-once 1
	call {
		call 1stCrate
		call HomeNPC
		log 1st Crate done!
		call 2ndCrate
		call HomeNPC
		log 2nd Crate done!
		call 3rdCrate
		call HomeNPC
		log 3rd Crate done!
		call 4thCrate
		call HomeNPC
		log 4th Crate done!
		call 5thCrate
		call HomeNPC
		log 5th Crate done!
		log Quest Complete!
		stop
	}
}

automacro 6thBracket {
	console /You can easily recognize the first crate/
	base >= 98
	exclusive 1
	run-once 1
	call {
		call 1stCrate
		call HomeNPC
		log 1st Crate done!
		call 2ndCrate
		call HomeNPC
		log 2nd Crate done!
		call 3rdCrate
		call HomeNPC
		log 3rd Crate done!
		call 4thCrate
		call HomeNPC
		log 4th Crate done!
		call 5thCrate
		call HomeNPC
		log 5th Crate done!
		call 6thCrate
		call HomeNPC
		log 6th Crate done!
		log Quest Complete!
		stop
	}
}

macro 1stCrate {
	$randomX1 = @random ("187","188","189","190","191")
	$randomY1 = @random ("164","165","166","167","168")
	do move $randomX1 $randomY1
	pause 2
	$i = 0
	while ($i < 5) as loop
		do talknpc 188 173 c n
		$i++
	end loop
	stop
}

macro 2ndCrate {
	$randomX2 = @random ("224","225","226","227","228")
	$randomY2 = @random ("102","103","104","105","106")
	do move $randomX2 $randomY2
	pause 2
	$i = 0
	while ($i < 5) as loop
		do talknpc 232 104 c n
		$i++
	end loop
	stop
}

macro 3rdCrate {
	$randomX3 = @random ("238","239","240","241","242")
	$randomY3 = @random ("88","89","90","91","92")
	do move $randomX3 $randomY3
	pause 2
	$i = 0
	while ($i < 5) as loop
		do talknpc 246 87 c n
		$i++
	end loop
	stop
}

macro 4thCrate {
	$randomX4 = @random ("238","239","240","241","242")
	$randomY4 = @random ("64","65","66","67","68")
	do move $randomX4 $randomY4
	pause 2
	$i = 0
	while ($i < 5) as loop
		do talknpc 245 67 c n
		$i++
	end loop
	stop
}

macro 5thCrate {
	$randomX5 = @random ("235","236","237","238","239")
	$randomY5 = @random ("40","41","42","43","44")
	do move $randomX5 $randomY5
	pause 2
	$i = 0
	while ($i < 5) as loop
		do talknpc 243 43 c n
		$i++
	end loop
	stop
}


macro 6thCrate {
	$randomX6 = @random ("114","115","116","117","118")
	$randomY6 = @random ("215","216","217","218","219")
	do move alberta 105 153
	pause 2
	do move alberta 110 221
	pause 2
	do move $randomX6 $randomY6
	pause 2
	do talknpc 123 221 c n
	pause 2
	do move alberta 110 221
	pause 2
	do move alberta 105 153
	pause 2
	stop
}

macro HomeNPC {
	$randomHX = @random ("94","95","96","97","98")
	$randomHY = @random ("60","61","62","63","64")
	do move $randomHX $randomHY
	pause 2
	do talknpc 90 62 c n
	stop
}

i just change the regexp in answerBoats because after the bot correctly answer the number of boats, the NPC will ask again the bot with two questions, thus triggering the answerBoats again. im sorry if my english or my grammar was bad.

[ever_boy_]

However, the automacro "answerBoats" failed to initialize...

It's no wonder it fails to trigger... I gave you the wrong regex, sorry for that. Try this:

Code: Select all

automacro countBoats {
   console /^NPC \[Quest\] Port Manager# \(\d+\) shown minimap indicator/i
   call {
      [
      $i++
      ]
   }
}
automacro answerBoats {
   console /^\[Quest\] Port Manager#: Type/i
   call {
      do talk text $i
      $i = 0
   }
}

If something goes wrong, show me a complete sequence of this quest, manually talking to the npc.

[hjtjl]

Hey can you help me with my servertype.txt can u show me your servertype.txt because I'm also a player of ph RO and my servertype.txt are in bRO settings, I can't connect to poseidon server so that I can't login the lvl 99 novice character, it says failed to connect to server please help me out bro

[raine101]

Thanks for the quick response @ever_boy_

The macro that you have given is now working and the automacros are initializing...

However, the conversation with the npc isn't going too well...

I suspected that Kore isn't resetting "$i" back to 0 so I included a little automacro to check on this..

Code: Select all

automacro check {
	console /Done talking/i
	call {
		log Number of boats: $i
		}
	}

After running Kore, with the cargo quest macro, here's what I got...



As you can see, the automacro "answerBoats" did initialize and gave the right answer...

However, as I suspected, "$i" hasn't been reset back to 0 even if the "answerBoats" macro ends its sequence thus giving the NPC a wrong answer the next time Kore initiates a conversation...

So I was just thinking if there's any sure way we can reset "$i"'s value back to 0 with a macro or an independent automacro perhaps?

[ever_boy_]

Code: Select all

automacro resetBoats {
   console /^\[Quest\] Port Manager#: Done Talking/i
   call {
      $i = 0
   }
}

It seems that the npc-talking overrides the macros commands.

As EternalHarvest stated, this is not 100% reliable. Sometimes, lag or other unpredictable situations may prevent the macro from triggering, as it depends on a very quick succession of console lines.

[raine101]

Thanks for all the effort and assistance...

I've inserted some lines to be sure that Kore won't give any answer unless a response is already needed...

I'm still encountering some little errors, but I think I can already manage those...

Thank you very much and more power!

By the way, here's the code that I am using with your macros...

Just hoping that this will serve its purpose for the players from my country and server...

Code: Select all

automacro countBoats {
   console /^NPC \[Quest\] Port Manager# \(\d+\) shown minimap indicator/i
   call {
      [
      $i++
      ]
   }
}
automacro answerBoats {
   console /^\[Quest\] Port Manager#: Type 'talk text'/i
   call {
	  pause 5
      do talk text $i
     }
}

automacro answerBoats2 {
   console / MIMICs of all things!/i
   run-once 1
   delay 5
   call {
      do talk resp 0
      }
}

automacro resetBoats-a {
   console /^\[Quest\] Port Manager#: Here/i
   call {
      $i = 0
	  log Number of boats: $i
   }
}

automacro resetBoats-b {
   console /^\[Quest\] Port Manager#: Why/i
   call {
      $i = 0
	  log Number of boats: $i
   }
}

automacro resetBoats-c {
   console /^\[Quest\] Port Manager#: How can I help you?/i
   call {
      $i = 0
	  log Number of boats: $i
   }
}

Thanks again!

P.S.

I have inserted a checking line so that the player can be sure that the value of $i reset back to 0 after a conversation.

I'm just wondering if there's anyway we can change the color of the "log" part that appears on Kore's console so that it can be noticed even more. Thanks.

[arenole]

wow thats great.. can you pls post your complete macro for Cargo quest..

sorry im noob and no talent in this kind of program,,,

tnx - - -